path: root/configure.in

dnl Process this file with autoconf to produce a configure script.

AC_INIT(src/gcompris/gcompris.c)
AC_CANONICAL_HOST
AM_INIT_AUTOMAKE(gcompris, 8.5PRE3)
AM_CONFIG_HEADER(config.h)
AC_CONFIG_MACRO_DIR([m4])

AM_MAINTAINER_MODE

dnl libtool versioning from libgnome

AC_ISC_POSIX

GTK_REQUIRED=2.4.0

dnl
dnl Start of pkg-config checks
dnl

PKG_PROG_PKG_CONFIG()

PKG_CHECK_MODULES(GCOMPRIS, dnl
 [gtk+-2.0 >= $GTK_REQUIRED dnl
  gstreamer-0.10 dnl
  librsvg-2.0])

AC_SUBST(GCOMPRIS_CFLAGS)
AC_SUBST(GCOMPRIS_LIBS)

AC_HEADER_DIRENT

AC_PROG_CC
AM_PROG_CC_STDC
AM_PROG_CC_C_O
AC_HEADER_STDC

AC_PROG_INTLTOOL

AM_DISABLE_STATIC
AC_LIBTOOL_WIN32_DLL
AM_PROG_LIBTOOL

pkg_modules="gtk+-2.0 >= 2.10.0 glib-2.0 >= 2.10.0 librsvg-2.0"
PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
AC_SUBST(PACKAGE_CFLAGS)
AC_SUBST(PACKAGE_LIBS)

dnl for libart_lgpl
AC_FUNC_ALLOCA
AC_C_BIGENDIAN

dnl OSX Specifics
AC_MSG_CHECKING([for OSX])
case "$host" in
  *-apple-darwin*)
    native_osx=yes
    OSX_CFLAGS="$CFLAGS -arch i386 -arch ppc "
    ;;
  *)
    native_osx=no
    OSX_CFLAGS=""
    ;;
esac
AC_MSG_RESULT([$native_osx])

AM_CONDITIONAL(OS_MACOSX, test "$native_osx" = yes)

# nsbundle default is no even for osx
nsbundle="no"

AC_ARG_ENABLE(nsbundle,
          AC_HELP_STRING(
          [--enable-nsbundle],
          [Turn on nsbundle packaging (needs Cocoa/GNUstep)]),
          nsbundle="$enableval", nsbundle="no")

NSBUNDLE_CPPFLAGS=
NSBUNDLE_LDFLAGS=
NSBUNDLE_GTK_DIR=

#check header for nsbundle
if test "x$nsbundle" = "xyes"; then
   AC_PROG_OBJC([gcc])
   AC_PROG_OBJCPP([gcc])

   if test "x$native_osx" = "xyes"; then
      AC_LANG_PUSH([Objective C])
      AC_CHECK_HEADER(Foundation/Foundation.h, NSFoundation="yes" , NSFoundation="no")
      if test "x$NSFoundation" = "x$no"; then
	 AC_MSG_ERROR([You need development tools to use nsbundle. Make sure XCode is installed." ])
      fi
      NSBUNDLE_GTK_DIR="/../GTK"
      NSBUNDLE_LDFLAGS="-framework Cocoa "
      OBJCFLAGS="$OBJCFLAGS $CFLAGS"
      AC_LANG_POP([Objective C])
   else
      AC_LANG_PUSH([Objective C])
      saved_CPPFLAGS="$CPPFLAGS"
      if test "x$GNUSTEP_SYSTEM_ROOT" != "x"; then
         CPPFLAGS="$CPPFLAGS -I$GNUSTEP_SYSTEM_ROOT/Library/Headers "
      fi
      AC_CHECK_HEADER(Foundation/Foundation.h, NSFoundation="yes" , NSFoundation="no")
      if test "x$NSFoundation" = "xno"; then
         AC_MSG_ERROR([You need GNUstep dev to use nsbundle. Make sure GNUSTEP_SYSTEM_ROOT is set." ])
      fi
      CPPFLAGS="$saved_CPPFLAGS"
      OBJCFLAGS="$OBJCFLAGS $CFLAGS -DGNUSTEP -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGNUSTEP_BASE_LIBRARY=1 -fconstant-string-class=NSConstantString -I$GNUSTEP_SYSTEM_ROOT/Library/Headers "
      NSBUNDLE_GTK_DIR="/GTK"
      NSBUNDLE_LDFLAGS="-rdynamic -fgnu-runtime -L$GNUSTEP_SYSTEM_ROOT/Library/Libraries -lgnustep-base -lgnustep-gui -Wl,-rpath=\\\$\$ORIGIN/$NSBUNDLE_GTK_DIR/lib "
      AC_LANG_POP([Objective C])
   fi
   AC_DEFINE_UNQUOTED(NSBUNDLE, 1, [ Define to 1 to use NSBundle for relocation (OSX/GNUstep) ])
   AC_DEFINE_UNQUOTED(NSBUNDLE_GTK_DIR, "$NSBUNDLE_GTK_DIR", [ Define to 1 to use NSBundle for relocation (OSX/GNUstep) ])
else
OBJC=$CC
AC_SUBST(OBJC)
fi

_AM_DEPENDENCIES([OBJC])

AC_SUBST(NSBUNDLE_CPPFLAGS)
AC_SUBST(NSBUNDLE_LDFLAGS)
AC_SUBST(NSBUNDLE_GTK_DIR)

# Todo: add a AC_ARG_WITH to allow change.
bundlename=GCompris


nsbundledir=$(pwd)"/$bundlename.app"
BUNDLE_APPDIR="$nsbundledir"
BUNDLE_NAME="$bundlename"
AC_SUBST(BUNDLE_APPDIR)
AC_SUBST(BUNDLE_NAME)

AM_CONDITIONAL(WITH_NSBUNDLE, test "$nsbundle" = yes)


# Provide relocatable API from autopackage
# From http://autopackage.org/docs/binreloc/
enable_binreloc=auto
if test x"$nsbundle" = "xyes" ; then
enable_binreloc=no
AC_MSG_NOTICE([binreloc disabled by nsbundle])
fi

AM_BINRELOC

dnl GNOME2 GNOME_X_CHECKS
AM_PATH_GLIB_2_0

dnl libxml-2 Checks
PKG_CHECK_MODULES(XML, libxml-2.0)
AC_SUBST(XML_CFLAGS)
AC_SUBST(XML_LIBS)

dnl Freetype2 flags (needed for libgnomecanvas)
PKG_CHECK_MODULES(FT2, freetype2)
AC_SUBST(FT2_CFLAGS)

dnl glib-genmarshal
GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
AC_SUBST(GLIB_GENMARSHAL)

GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
AC_SUBST(GLIB_MKENUMS)

AC_ARG_ENABLE(rebuilds,
              [AC_HELP_STRING([--disable-rebuilds],
                              [disable all source autogeneration rules])],,
              [enable_rebuilds=yes])

# define a MAINT-like variable REBUILD which is set if Perl
# and awk are found, so autogenerated sources can be rebuilt
AC_PATH_PROGS(PERL, perl5 perl)
REBUILD=\#
if test "x$enable_rebuilds" = "xyes" && \
     test -n "$PERL" && \
     $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
  REBUILD=
fi
AC_SUBST(REBUILD)

LDFLAGS="${LDFLAGS}"

dnl Add the languages which your application supports here.
ALL_LINGUAS="af am ar az bg br ca cs da de dz el en_CA en_GB es et eu fa fi fr ga gl gu he hi hr hu id it ja ka ko lt mk ml mr ms nb ne nl nn oc pa pl pt pt_BR ro ru rw sk sl so sq sr sr@Latn sv ta th tr uk ur vi wa zh_CN zh_TW"

dnl GCompris needs to know which locale are supported
AC_SUBST(ALL_LINGUAS)
AC_DEFINE_UNQUOTED(ALL_LINGUAS, "${ALL_LINGUAS}", [Supported languages])

GETTEXT_PACKAGE=gcompris
AC_SUBST(GETTEXT_PACKAGE)

AM_GLIB_GNU_GETTEXT

AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package name])

BUILD_DATE=`date +%y%m`
AC_DEFINE_UNQUOTED(BUILD_DATE,"$BUILD_DATE", [Date at which GCompris has been built])
AC_SUBST(BUILD_DATE)

dnl Define myprefix depending on wether our user gives us one or not
if test "x${prefix}" = "xNONE"; then
  myprefix=${ac_default_prefix}
else
  myprefix=${prefix}
fi

dnl Define myprefix depending on wether our user gives us one or not
dnl This is needed for $libdir !
if test "x${exec_prefix}" = "xNONE"; then
  exec_prefix=${myprefix}
fi



dnl Some debug option
AC_ARG_ENABLE(debug,
          AC_HELP_STRING(
          [--enable-debug],
          [Turn on debugging messages]),
          USE_DEBUG="$enableval", USE_DEBUG="no")
if test "x$USE_DEBUG" == "xyes" ; then
    AC_DEFINE_UNQUOTED(DEBUG, 1, "Enable debug messages.")
    CFLAGS="$CFLAGS $OSX_CFLAGS -Wall -Werror -g"
else
    CFLAGS="$CFLAGS $OSX_CFLAGS -Wall -Werror"
fi

dnl Checking for the presence of the colorblind library.
AC_CHECK_LIB(colorblind, colorblind_create, COLORBLIND_LIBS=-lcolorblind, have_colorblind=no)
if test "x$COLORBLIND_LIBS" != "x" ; then
    AC_CHECK_HEADERS([colorblind.h], have_colorblind=yes, have_colorblind=no)
dnl    AC_DEFINE(HAVE_LIBCOLORBLIND, 1, [The colorblind library is present.])
fi

dnl WIN32 Specifics
AC_MSG_CHECKING([for Win32 platform in general])
case "$host" in
  *-*-mingw*|*-*-cygwin*)
    platform_win32=yes
    ;;
  *)
    platform_win32=no
    ;;
esac
AC_MSG_RESULT($platform_win32)
AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = yes)
AM_CONDITIONAL(BUILD_MINGW32, test "$platform_win32" = yes)
if test x"$platform_win32" = xyes; then
   LIBS="$LIBS -luuid -lole32 -lwsock32 -mno-cygwin -mms-bitfields -mwindows -mconsole"
   #CFLAGS="$CFLAGS -D__GW32__ -DWIN32 -I$CROSS_ROOT/include -I$CROSS_ROOT/include/glibc"
   #CFLAGS="$CFLAGS -DWIN32"
fi


# Ensure MSVC-compatible struct packing convention is used when
# compiling for Win32 with gcc. GTK+ uses this convention, so we must, too.
# What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
# gcc2 uses "-fnative-struct".
if test x"$native_win32" = xyes; then
  if test x"$GCC" = xyes; then
    msnative_struct=''
    AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
    if test -z "$ac_cv_prog_CC"; then
      our_gcc="$CC"
    else
      our_gcc="$ac_cv_prog_CC"
    fi
    case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
      2.)
	if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
	  msnative_struct='-fnative-struct'
	fi
	;;
      *)
	if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
	  msnative_struct='-mms-bitfields'
	fi
	;;
    esac
    if test x"$msnative_struct" = x ; then
      AC_MSG_RESULT([no way])
      AC_MSG_WARN([produced libraries will be incompatible with prebuilt GTK+ DLLs])
    else
      CFLAGS="$CFLAGS $msnative_struct"
      AC_MSG_RESULT([${msnative_struct}])
    fi
  fi
fi

dnl
dnl === DIRECTORY DEFINITIONS ===
dnl

if test "x$platform_win32" = "xno" ; then

  dnl Set PACKAGE_LOCALE_DIR in config.h.
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${myprefix}/${DATADIRNAME}/locale", [GCompris locale directory])

  dnl Set PACKAGE_DATA_DIR
  PACKAGE_DATA_DIR="boards"
  AC_SUBST(PACKAGE_DATA_DIR)
  AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${myprefix}/${DATADIRNAME}", [GCompris data directory])

  dnl Set PACKAGE_HELP_DIR
  PACKAGE_HELP_DIR="${myprefix}/${DATADIRNAME}/${PACKAGE}/help"
  AC_SUBST(PACKAGE_HELP_DIR)

  dnl Plugin Directory
  my_libdir=`eval echo "${libdir}"`
  AC_DEFINE_UNQUOTED(PACKAGE_CLIB_DIR, "${my_libdir}", [Gcompris plugins directory])
  plugindir=$libdir/gcompris
  AC_SUBST(plugindir)

  dnl Python plugin Directory
  PYTHON_PLUGIN_DIR="${myprefix}/${DATADIRNAME}/${PACKAGE}/python"
  AC_SUBST(PYTHON_PLUGIN_DIR)

  dnl System GCompris config directory
  AC_DEFINE_UNQUOTED(SYSTEM_CONFIG_DIR, "/etc", [System GCompris config directory])

else
  DATADIRNAME="share"

  dnl Set PACKAGE_LOCALE_DIR in config.h for WINDOWS
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "../${DATADIRNAME}/locale", [GCompris locale directory])

  dnl Set PACKAGE_DATA_DIR
  PACKAGE_DATA_DIR="boards"
  AC_SUBST(PACKAGE_DATA_DIR)
  AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "../${DATADIRNAME}", [GCompris data directory])

  dnl Set PACKAGE_HELP_DIR
  PACKAGE_HELP_DIR="${myprefix}/${DATADIRNAME}/gnome/help/gcompris"
  AC_SUBST(PACKAGE_HELP_DIR)

  dnl Plugin Directory
  AC_DEFINE_UNQUOTED(PACKAGE_CLIB_DIR, "../${DATADIRNAME}", [Gcompris plugins directory])
  plugindir=${myprefix}/${DATADIRNAME}/gcompris
  AC_SUBST(plugindir)

  dnl Python plugin Directory
  PYTHON_PLUGIN_DIR="${myprefix}/${DATADIRNAME}/gcompris/python"
  AC_SUBST(PYTHON_PLUGIN_DIR)

fi

dnl Test for gnuchess
AC_PATH_PROGS(GNUCHESS, gnuchess gnome-gnuchess, no, [/usr/bin:/usr/games:/usr/local/bin:$PATH])

if test x$GNUCHESS = xno; then
  AC_MSG_ERROR(Couldn't find gnuchess, please install the gnuchess package version 5 or above)
fi
AC_DEFINE_UNQUOTED(GNUCHESS, "$GNUCHESS", Defines where GNU Chess resides on the system)

AC_PATH_PROG(TEXINFO, makeinfo,no)
if test x$TEXINFO = xno; then
  AC_MSG_WARN(Couldn't find texinfo, docs are not compiled. please install the texinfo package)
fi
AM_CONDITIONAL(TEXINFO, test x$TEXINFO != xno)

AC_PATH_PROG(TETEX, texi2html,no)
if test x$TETEX = xno; then
  AC_MSG_WARN(Couldn't find texi2html usualy in the tetex package, please install it)
fi


dnl GNET support
AC_MSG_CHECKING([wether we build with GNET (if not, networking will be disabled)])
AC_ARG_ENABLE(gnet,
          AC_HELP_STRING(
          [--disable-gnet],
          [Turn off gnet (will not let GCompris fetch content from a web server)]),
          with_gnet="$enableval", with_gnet="yes")
AC_MSG_RESULT($with_gnet)

if test x$with_gnet = xyes; then
  PKG_CHECK_MODULES(GNET, gnet-2.0,, AC_MSG_ERROR([*** GNET not found!]))
  AC_DEFINE([USE_GNET], 1,[Networking is enabled])
fi

dnl SQLITE support
AC_MSG_CHECKING([wether we build with SQLITE (if not profile will be disabled)])
AC_ARG_ENABLE(sqlite,
          AC_HELP_STRING(
          [--disable-sqlite],
          [Turn off sqlite (will disable profile)]),
          with_sqlite="$enableval", with_sqlite="yes")
AC_MSG_RESULT($with_sqlite)

dnl DBUS support (Needed only for OLPC XO)
AC_MSG_CHECKING([wether we build with DBUS (needed only for OLPC SUGAR XO)])
AC_ARG_ENABLE(dbus,
          AC_HELP_STRING(
          [--enable-dbus],
          [Turn on dbus (will let GCompris integrate well on OLPC SUGAR XO)]),
          with_dbus="$enableval", with_dbus="no")
AC_MSG_RESULT($with_dbus)

if test x$with_dbus = xyes; then
  PKG_CHECK_MODULES(DBUS, [dbus-1 dbus-glib-1],, AC_MSG_ERROR([*** DBUS not found!]))
  AC_DEFINE([USE_DBUS], 1,[DBUS support is enabled])
fi

dnl check for python
AC_ARG_WITH(python,AC_HELP_STRING(
    [--with-python=path],
    [set the path for python]), python_path=$withval, python_path=not)
if test x$python_path = xno ; then
build_python_plugin="no"
else


if test x$python_path != xnot ; then
PYTHON=$python_path
fi

AM_PATH_PYTHON(2.2)
AM_CHECK_PYTHON_HEADERS( [build_python_plugin="yes"], [build_python_plugin="no"] )

fi

dnl Finally output the required python variables and automake defines.
AM_CONDITIONAL(PYTHON_PLUGIN, test x$build_python_plugin = xyes)

dnl build only support
AC_ARG_ENABLE(py-build-only,
          AC_HELP_STRING(
          [--enable-py-build-only],
          [Skip python modules tests. (Useful if you just need build)]),
          py_build_only="$enableval", py_build_only="no")

REQUIRE_PYTHON=""
if test x$build_python_plugin = xno; then
  AC_MSG_NOTICE([Python plugin is disabled.])
else
  dnl Python interpreter is available so check for pygtk
  PKG_CHECK_MODULES(PYGTK, pygtk-2.0 pycairo)

  AC_MSG_CHECKING([for pygtk defs])
  PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
  AC_MSG_RESULT([$PYGTK_DEFSDIR])

  AC_MSG_CHECKING([for pygtk codegen])
  PYGTK_CODEGEN="$PYTHON `$PKG_CONFIG --variable=codegendir pygtk-2.0`/codegen.py"
  AC_MSG_RESULT([$PYGTK_CODEGEN])

  AC_MSG_CHECKING([for pygtk h2def])
  PYGTK_H2DEF="$PYTHON `$PKG_CONFIG --variable=codegendir pygtk-2.0`/h2def.py"
  AC_MSG_RESULT([$PYGTK_H2DEF])

  AC_SUBST([PYGTK_DEFSDIR])
  AC_SUBST([PYGTK_CODEGEN])
  AC_SUBST([PYGTK_H2DEF])

  if test x$py_build_only = xno; then
    AM_CHECK_PYMOD(gtk,,,AC_MSG_ERROR([*** pygtk installed but not visible from python ]))
    dnl AM_CHECK_PYMOD(xml.dom.DOMImplementation,,,AC_MSG_WARN([*** pyxml missing ]))

    dnl Set this variable for the .spec.in file
    REQUIRE_PYTHON="python pygtk2.0"

    dnl with gnome-python >= 2.10 gnome.canvas is obsolete. use gnomecanvas
    dnl gnomecanvas not supported yet in gcompris
    dnl
    dnl   AM_CHECK_PYMOD(gnome.canvas,,test_gnomecanvas="no",test_gnomevanvas="yes")
    dnl  if test x$test_gnomecanvas = xyes ; then
    dnl     AM_CHECK_PYMOD(gnomecanvas,,,AC_MSG_ERROR([*** gnome.canvas or gnomecanvas installed but not visible from python ]))
    dnl   fi

    if test x$with_sqlite = xyes; then
	AM_CHECK_PYMOD(pysqlite2,,,AC_MSG_ERROR([*** pysqlite2 missing ]))
	REQUIRE_PYTHON="$REQUIRE_PYTHON python-sqlite2"
    fi

  else
    AC_MSG_WARN([py-build-only: Skipping python modules dependancies])
    AC_MSG_WARN([py-build-only: Do not forget to install pygtk, pysqlite2])
  fi

fi

if test x$with_sqlite = xyes; then
    PKG_CHECK_MODULES(SQLITE3, sqlite3,, AC_MSG_ERROR([*** SQLITE3 not found!]))
    AC_DEFINE([USE_SQLITE], 1,[SQLITE Database, Profiles are enabled])
fi

AM_CONDITIONAL(USE_SQLITE, test x$with_sqlite = xyes)
AC_SUBST(SQLITE3_CFLAGS)
AC_SUBST(SQLITE3_LIBS)

AC_SUBST(REQUIRE_PYTHON)

dnl mingw32 specific stuff.
dnl use libgw32c
dnl define __GW32__ and WIN32

# Check platform - see if WinMain needed:
AC_SUBST(CFLAGS)
AC_SUBST(LIBS)

dnl disable activation code
AC_ARG_ENABLE(activation-code,
          AC_HELP_STRING(
          [--disable-activation-code],
          [For Windows version, disable the activation code]),
          activation_code="$enableval", activation_code="yes")

if test x$activation_code = xno; then
  AC_DEFINE([DISABLE_ACTIVATION_CODE], 1,[Activation code is disabled])
fi

dnl Autoconf output
AC_OUTPUT([ Makefile.mingw
Makefile
autopackage/Makefile
autopackage/default.apspec
boards/Makefile
config.h.mingw
docs/C/Makefile
docs/Makefile
docs/eu/Makefile
docs/fr/Makefile
gcompris-installer.nsi
macosx/Makefile
po/Makefile.in
src/Makefile
src/administration-activity/Makefile
src/administration-activity/admin/Makefile
src/administration-activity/resources/Makefile
src/administration-activity/resources/administration/Makefile
src/advanced_colors-activity/Makefile
src/advanced_colors-activity/resources/Makefile
src/advanced_colors-activity/resources/advanced_colors/Makefile
src/algebra_by-activity/Makefile
src/algebra_by-activity/resources/Makefile
src/algebra_by-activity/resources/algebra/Makefile
src/algebra_guesscount-activity/Makefile
src/algebra_guesscount-activity/resources/Makefile
src/algebra_guesscount-activity/resources/algebra_guesscount/Makefile
src/algebra_minus-activity/Makefile
src/algebra_plus-activity/Makefile
src/algorithm-activity/Makefile
src/algorithm-activity/resources/Makefile
src/algorithm-activity/resources/algorithm/Makefile
src/anim-activity/Makefile
src/anim-activity/resources/Makefile
src/anim-activity/resources/anim/Makefile
src/awele-activity/Makefile
src/awele-activity/resources/Makefile
src/awele-activity/resources/awele/Makefile
src/babymatch-activity/Makefile
src/babymatch-activity/resources/Makefile
src/babymatch-activity/resources/babymatch/Makefile
src/babymatch-activity/resources/shapegame/Makefile
src/babyshapes-activity/Makefile
src/babyshapes-activity/resources/Makefile
src/babyshapes-activity/resources/babyshapes/Makefile
src/babyshapes-activity/resources/babyshapes/dog1/Makefile
src/babyshapes-activity/resources/babyshapes/dog2/Makefile
src/babyshapes-activity/resources/babyshapes/dog3/Makefile
src/babyshapes-activity/resources/babyshapes/food/Makefile
src/ballcatch-activity/Makefile
src/ballcatch-activity/resources/Makefile
src/ballcatch-activity/resources/ballcatch/Makefile
src/bargame-activity/Makefile
src/bargame-activity/resources/Makefile
src/bargame-activity/resources/bargame/Makefile
src/billard-activity/Makefile
src/billard-activity/resources/Makefile
src/billard-activity/resources/billard/Makefile
src/boards/Makefile
src/boards/python/Makefile
src/boards/python/gcompris/Makefile
src/boards/python/gcompris/admin/Makefile
src/boards/python/gcompris/anim/Makefile
src/boards/python/gcompris/bonus/Makefile
src/boards/python/gcompris/score/Makefile
src/boards/python/gcompris/skin/Makefile
src/boards/python/gcompris/sound/Makefile
src/boards/python/gcompris/timer/Makefile
src/boards/python/gcompris/utils/Makefile
src/canal_lock-activity/Makefile
src/canal_lock-activity/resources/Makefile
src/canal_lock-activity/resources/canal_lock/Makefile
src/chat-activity/Makefile
src/chess_computer-activity/Makefile
src/chess_computer-activity/resources/Makefile
src/chess_computer-activity/resources/chess/Makefile
src/chess_movelearn-activity/Makefile
src/chess_partyend-activity/Makefile
src/chronos-activity/Makefile
src/chronos-activity/resources/Makefile
src/chronos-activity/resources/chronos/Makefile
src/click_on_letter-activity/Makefile
src/click_on_letter-activity/resources/Makefile
src/click_on_letter-activity/resources/click_on_letter/Makefile
src/clickanddraw-activity/Makefile
src/clickgame-activity/Makefile
src/clickgame-activity/resources/Makefile
src/clickgame-activity/resources/clickgame/Makefile
src/clockgame-activity/Makefile
src/clockgame-activity/resources/Makefile
src/clockgame-activity/resources/clockgame/Makefile
src/colors-activity/Makefile
src/colors-activity/resources/Makefile
src/colors-activity/resources/colors/Makefile
src/connect4-2players-activity/Makefile
src/connect4-activity/Makefile
src/connect4-activity/connect4p/Makefile
src/connect4-activity/resources/Makefile
src/connect4-activity/resources/connect4/Makefile
src/crane-activity/Makefile
src/crane-activity/resources/Makefile
src/crane-activity/resources/crane/Makefile
src/doubleentry-activity/Makefile
src/doubleentry-activity/resources/Makefile
src/doubleentry-activity/resources/doubleentry/Makefile
src/draw-activity/Makefile
src/drawnumber-activity/Makefile
src/drawnumber-activity/resources/Makefile
src/drawnumber-activity/resources/drawnumber/Makefile
src/electric-activity/Makefile
src/electric-activity/resources/Makefile
src/electric-activity/resources/electric/Makefile
src/enumerate-activity/Makefile
src/enumerate-activity/resources/Makefile
src/enumerate-activity/resources/enumerate/Makefile
src/erase-activity/Makefile
src/erase-activity/resources/Makefile
src/erase-activity/resources/erase/Makefile
src/erase_clic-activity/Makefile
src/fifteen-activity/Makefile
src/fifteen-activity/resources/Makefile
src/fifteen-activity/resources/fifteen/Makefile
src/followline-activity/Makefile
src/followline-activity/resources/Makefile
src/followline-activity/resources/followline/Makefile
src/gcompris/Makefile
src/geo_country-activity/Makefile
src/geo_country-activity/resources/Makefile
src/geo_country-activity/resources/geo_country/Makefile
src/geo_country-activity/resources/geo_country/argentina/Makefile
src/geo_country-activity/resources/geo_country/brazil/Makefile
src/geo_country-activity/resources/geo_country/canada/Makefile
src/geo_country-activity/resources/geo_country/france/Makefile
src/geo_country-activity/resources/geo_country/germany/Makefile
src/geo_country-activity/resources/geo_country/mexico/Makefile
src/geo_country-activity/resources/geo_country/norway/Makefile
src/geo_country-activity/resources/geo_country/poland/Makefile
src/geo_country-activity/resources/geo_country/turkey/Makefile
src/geography-activity/Makefile
src/geography-activity/resources/Makefile
src/geography-activity/resources/geography/Makefile
src/geography-activity/resources/geography/africa/Makefile
src/geography-activity/resources/geography/afrique/Makefile
src/geography-activity/resources/geography/continents/Makefile
src/geography-activity/resources/geography/europe/Makefile
src/geography-activity/resources/geography/northamerica/Makefile
src/geography-activity/resources/geography/southamerica/Makefile
src/gletters-activity/Makefile
src/gletters-activity/resources/Makefile
src/gletters-activity/resources/gletters/Makefile
src/gnumch-equality-activity/Makefile
src/gnumch-equality-activity/resources/Makefile
src/gnumch-equality-activity/resources/gnumch/Makefile
src/gnumch-factors-activity/Makefile
src/gnumch-inequality-activity/Makefile
src/gnumch-multiples-activity/Makefile
src/gnumch-primes-activity/Makefile
src/goocanvas/Makefile
src/goocanvas/src/Makefile
src/guessnumber-activity/Makefile
src/guessnumber-activity/resources/Makefile
src/guessnumber-activity/resources/guessnumber/Makefile
src/hanoi-activity/Makefile
src/hanoi_real-activity/Makefile
src/hanoi_real-activity/resources/Makefile
src/hanoi_real-activity/resources/hanoi_real/Makefile
src/hexagon-activity/Makefile
src/hexagon-activity/resources/Makefile
src/hexagon-activity/resources/hexagon/Makefile
src/imageid-activity/Makefile
src/imageid-activity/resources/Makefile
src/imageid-activity/resources/imageid/Makefile
src/imagename-activity/Makefile
src/imagename-activity/resources/Makefile
src/imagename-activity/resources/imagename/Makefile
src/leftright-activity/Makefile
src/leftright-activity/resources/Makefile
src/leftright-activity/resources/leftright/Makefile
src/login-activity/Makefile
src/login-activity/resources/Makefile
src/login-activity/resources/login/Makefile
src/magic_hat_minus-activity/Makefile
src/magic_hat_minus-activity/resources/Makefile
src/magic_hat_minus-activity/resources/magic_hat/Makefile
src/magic_hat_plus-activity/Makefile
src/maze-activity/Makefile
src/maze-activity/resources/Makefile
src/maze-activity/resources/maze/Makefile
src/maze2DRelative-activity/Makefile
src/maze3D-activity/Makefile
src/mazeInvisible-activity/Makefile
src/melody-activity/Makefile
src/melody-activity/resources/Makefile
src/melody-activity/resources/melody/Makefile
src/memory-activity/Makefile
src/memory-activity/resources/Makefile
src/memory-activity/resources/memory/Makefile
src/memory_add-activity/Makefile
src/memory_add_minus-activity/Makefile
src/memory_add_minus_mult_div-activity/Makefile
src/memory_add_minus_mult_div_tux-activity/Makefile
src/memory_add_minus_tux-activity/Makefile
src/memory_add_tux-activity/Makefile
src/memory_div-activity/Makefile
src/memory_div_tux-activity/Makefile
src/memory_enumerate-activity/Makefile
src/memory_minus-activity/Makefile
src/memory_minus_tux-activity/Makefile
src/memory_mult-activity/Makefile
src/memory_mult_div-activity/Makefile
src/memory_mult_div_tux-activity/Makefile
src/memory_mult_tux-activity/Makefile
src/memory_sound-activity/Makefile
src/memory_sound_tux-activity/Makefile
src/memory_tux-activity/Makefile
src/memory_wordnumber-activity/Makefile
src/missing_letter-activity/Makefile
src/missing_letter-activity/resources/Makefile
src/missing_letter-activity/resources/missing_letter/Makefile
src/money-activity/Makefile
src/money-activity/resources/Makefile
src/money-activity/resources/money/Makefile
src/money_cents-activity/Makefile
src/mosaic-activity/Makefile
src/mosaic-activity/resources/Makefile
src/mosaic-activity/resources/mosaic/Makefile
src/paintings-activity/Makefile
src/paintings-activity/resources/Makefile
src/paintings-activity/resources/paintings/Makefile
src/paratrooper-activity/Makefile
src/paratrooper-activity/resources/Makefile
src/paratrooper-activity/resources/paratrooper/Makefile
src/penalty-activity/Makefile
src/penalty-activity/resources/Makefile
src/penalty-activity/resources/penalty/Makefile
src/photohunter-activity/Makefile
src/photohunter-activity/resources/Makefile
src/photohunter-activity/resources/photohunter/Makefile
src/planegame-activity/Makefile
src/planegame-activity/resources/Makefile
src/planegame-activity/resources/planegame/Makefile
src/pythontemplate-activity/Makefile
src/pythontest-activity/Makefile
src/railroad-activity/Makefile
src/railroad-activity/resources/Makefile
src/railroad-activity/resources/railroad/Makefile
src/read_colors-activity/Makefile
src/read_colors-activity/resources/Makefile
src/read_colors-activity/resources/read_colors/Makefile
src/readingh-activity/Makefile
src/readingh-activity/resources/Makefile
src/readingh-activity/resources/readingh/Makefile
src/readingh-activity/resources/wordsgame/Makefile
src/readingv-activity/Makefile
src/redraw-activity/Makefile
src/redraw-activity/resources/Makefile
src/redraw-activity/resources/redraw/Makefile
src/redraw_symmetrical-activity/Makefile
src/redraw_symmetrical-activity/resources/Makefile
src/redraw_symmetrical-activity/resources/redraw_symmetrical/Makefile
src/reversecount-activity/Makefile
src/reversecount-activity/resources/Makefile
src/reversecount-activity/resources/reversecount/Makefile
src/scalesboard-activity/Makefile
src/scalesboard-activity/resources/Makefile
src/scalesboard-activity/resources/scale/Makefile
src/searace-activity/Makefile
src/searace-activity/resources/Makefile
src/searace-activity/resources/searace/Makefile
src/searace1player-activity/Makefile
src/smallnumbers-activity/Makefile
src/smallnumbers-activity/resources/Makefile
src/smallnumbers-activity/resources/smallnumbers/Makefile
src/smallnumbers2-activity/Makefile
src/submarine-activity/Makefile
src/submarine-activity/resources/Makefile
src/submarine-activity/resources/submarine/Makefile
src/sudoku-activity/Makefile
src/sudoku-activity/resources/Makefile
src/sudoku-activity/resources/sudoku/Makefile
src/superbrain-activity/Makefile
src/superbrain-activity/resources/Makefile
src/superbrain-activity/resources/superbrain/Makefile
src/tangram-activity/Makefile
src/tangram-activity/resources/Makefile
src/tangram-activity/resources/tangram/Makefile
src/target-activity/Makefile
src/target-activity/resources/Makefile
src/target-activity/resources/target/Makefile
src/traffic-activity/Makefile
src/traffic-activity/resources/Makefile
src/traffic-activity/resources/traffic/Makefile
src/tuxpaint-activity/Makefile
src/watercycle-activity/Makefile
src/watercycle-activity/resources/Makefile
src/watercycle-activity/resources/watercycle/Makefile
src/wordprocessor-activity/Makefile
src/wordprocessor-activity/resources/Makefile
src/wordprocessor-activity/resources/wordprocessor/Makefile
src/wordsgame-activity/Makefile
])

echo ""
echo "***************************************************"
echo ""
echo configure complete,
echo with options:

echo "Force python (--enable-py-build-only)    = $py_build_only"
echo "Python plugin                            = $build_python_plugin"

echo "SQLITE database (--enable-sqlite)        = $with_sqlite (profiles depend on this)"

echo "DBUS Support (OLPC XO Sugar)             = $with_dbus"
echo "GNET Networking (--enable-gnet)          = $with_gnet (networking depends on this)"
echo "BINRELOC (--enable-binreloc)             = $br_cv_binreloc"
echo "NSBundle (--enable-nsbundle)             = $nsbundle"
echo "Colorblind support                       = $have_colorblind"


echo
echo gcompris will be installed in ${prefix}
echo to compile and install in in another directory
echo type sh configure --prefix=/usr
echo
echo type \'make\' to compile gcompris
echo type \'make install\' to install it