1 files changed, 71 insertions, 0 deletions
diff --git a/vim71/ftplugin/php.vim b/vim71/ftplugin/php.vim
new file mode 100644
index 0000000..86cf89c
--- /dev/null
+++ b/vim71/ftplugin/php.vim
@@ -0,0 +1,71 @@
+" Vim filetype plugin file
+" Language:	php
+" Maintainer:	Dan Sharp <dwsharp at hotmail dot com>
+" Last Changed: 2006 Jul 15
+" URL:		http://mywebpage.netscape.com/sharppeople/vim/ftplugin
+
+if exists("b:did_ftplugin") | finish | endif
+
+" Make sure the continuation lines below do not cause problems in
+" compatibility mode.
+let s:save_cpo = &cpo
+set cpo-=C
+
+" Define some defaults in case the included ftplugins don't set them.
+let s:undo_ftplugin = ""
+let s:browsefilter = "HTML Files (*.html, *.htm)\t*.html;*.htm\n" .
+	    \	     "All Files (*.*)\t*.*\n"
+let s:match_words = ""
+
+runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
+let b:did_ftplugin = 1
+
+" Override our defaults if these were set by an included ftplugin.
+if exists("b:undo_ftplugin")
+    let s:undo_ftplugin = b:undo_ftplugin
+endif
+if exists("b:browsefilter")
+    let s:browsefilter = b:browsefilter
+endif
+if exists("b:match_words")
+    let s:match_words = b:match_words
+endif
+if exists("b:match_skip")
+    unlet b:match_skip
+endif
+
+" Change the :browse e filter to primarily show PHP-related files.
+if has("gui_win32")
+    let  b:browsefilter="PHP Files (*.php)\t*.php\n" . s:browsefilter
+endif
+
+" ###
+" Provided by Mikolaj Machowski <mikmach at wp dot pl>
+setlocal include=\\\(require\\\|include\\\)\\\(_once\\\)\\\?
+setlocal iskeyword+=$
+if exists("loaded_matchit")
+    let b:match_words = '<?php:?>,\<switch\>:\<endswitch\>,' .
+		      \ '\<if\>:\<elseif\>:\<else\>:\<endif\>,' .
+		      \ '\<while\>:\<endwhile\>,' .
+		      \ '\<do\>:\<while\>,' .
+		      \ '\<for\>:\<endfor\>,' .
+		      \ '\<foreach\>:\<endforeach\>,' .
+                      \ '(:),[:],{:},' .
+		      \ s:match_words
+endif
+" ###
+
+if exists('&ofu')
+  setlocal ofu=phpcomplete#CompletePHP
+endif
+
+
+setlocal commentstring=/*%s*/
+
+" Undo the stuff we changed.
+let b:undo_ftplugin = "setlocal cms< inc< isk<" .
+	    \	      " | unlet! b:browsefilter b:match_words | " .
+	    \	      s:undo_ftplugin
+
+" Restore the saved compatibility options.
+let &cpo = s:save_cpo